Animate Sprites toward a point

I'm trying to do something very simple: animate a bunch of sprites so that, no matter where they are on the stage, they all go toward a single point (in this case, the center of the stage).

It only works for some of them. Some of them just sit there. I can't figure out why. I think its got something to do with atan2 and the way I'm using it, but I'm not sure what. Can someone see?

Thanks,

David

package
{

import Ball;

import flash.display.Sprite;
import flash.display.StageAlign;
import flash.display.StageScaleMode;
import flash.events.Event;

public class MoveBalls extends Sprite {

    private var balls:Array = new Array();
    private var speed:Number = new Number(10);

    public function MoveBalls() {
        init();
    }

    private function init():void {
        stage.align = StageAlign.TOP_LEFT;
        stage.scaleMode = StageScaleMode.NO_SCALE;

        for(var i:int = 0; i<30; i++)
        {
            var ball:Ball = new Ball(20);
            ball.x = getRandomNumber();
            if(ball.x > stage.开发者_C百科stageWidth) ball.x = stage.stageWidth -10;
            if(ball.x < 0) ball.x = 10;
            trace(ball.x);
            ball.y = getRandomNumber();
            if(ball.y >stage.stageHeight) ball.y = stage.stageHeight - 10;
            if(ball.y < 0) ball.y = 10;
            addChild(ball);
            balls.push(ball);
        }

        addEventListener(Event.ENTER_FRAME, onEnterFrame);
    }

    private function getRandomNumber():Number {
        var decider:Number = Math.random();
        if (decider < 0.5) {
            return Math.random()*1000;
        } else {
            return Math.random()*-1000;
        }
    }

    public function onEnterFrame(event:Event):void {

        var targetX:Number = stage.stageWidth/2;
        var targetY:Number = stage.stageHeight/2;
        for(var i:int=0; i < balls.length; i++)
        {
            var startX:Number = balls[i].x;
            var startY:Number = balls[i].y;
            var atanX:Number = (targetX - startX);
            var atanY:Number = (targetY - startY);
            if(atanX > .1)   //just stop when it's close enough to the center
            {
                var ang:Number  = Math.atan2(atanY, atanX);
                var xSpeed:Number = Math.cos(ang)*speed;
                var ySpeed:Number = Math.sin(ang)*speed;
                balls[i].x += xSpeed;
                balls[i].y += ySpeed;
            }
        }

    }
}
}

//ball class
package {
import flash.display.Sprite;

public class Ball extends Sprite {
    private var radius:Number;
    private var color:uint;

    public function Ball(radius:Number=40, color:uint=0xff0000) {
        this.radius = radius;
        this.color = color;
        init();
    }
    public function init():void {
        graphics.beginFill(color);
        graphics.drawCircle(0, 0, radius);
        graphics.endFill();
    }
}
} 

I don't agree with this line:

if(atanX > .1)

Because if the balls are to go to the CENTER of the stage, like both on X and Y axes, then this condition fails for balls directly under or above the center.

Make it like this

 if (atanX > .1 || atanY > .1)

= If either of the differences are bigger than .1, go on with the atan2...

EDIT: One more obvious error - the atanX or atanY variables can, in 50% be negative. Therefore, use either this:

if (Math.abs(atanX) > .1 || Math.abs(atanY) > .1)

Or this, which is the same but faster (harder to read, though):

if ((atanX > 0 ? atanX : -atanX) > .1 || (atanY > 0 ? atanY : -atanY) > .1)