No more than 9 digits after separator with spark.formatters.NumberFormatter?

I must display very small values (capacitor) in a Flex-AdvancedDataGrid I use spark.formatters.NumberFormatter. If I use 3, 6 or 9 for fractionalDigits, everything is fine.

But if I use 12, because I need 12 digits after decimal separator, then the value is cut after 9 digits!

Is ther开发者_StackOverflow中文版e a way to get more then 9 digits after separator.

Or is there a way to use a formatting like "4.7 E-12" (Must be E-9, E-12, E-15 and so on)

toPrecision and toFixed works fine up to 20 digits. Thats enough. I will write a function on this base to get results like 4.7 E-12.

Thanks for the help Jan

I created a custom pattern formatter class that allows you to specify how you want a string/number formatted using whatever symbols or structure you want. Depending on your requirements, this may help you. Feel free to modify this class as needed.

CustomPatternFormatter.as

package
{
    import mx.formatters.Formatter;

    public class CustomPatternFormatter extends Formatter
    {
        private static const VALID_PATTERN_CHARACTERS:String = "#,.-";

        // Use # as a placeholder for a regular
        // character in the input string.
        // Then add other characters between the
        // # symbol for the desired output format.
        // ex. The pattern ##,##,##.## with input 12345678
        // will output 12,34,56.78
        public var formatPattern:String;

        // If True, the input string must match the number
        // of # characters in the formatPattern.
        public var inputMustMatchPatternLength:Boolean;

        //Constructor
        public function CustomPatternFormatter()
        {
            super();
            formatPattern = "";
            inputMustMatchPatternLength = false;
        }

        // Override format().
        override public function format(value:Object):String
        {
            // Reset error if it exists.
            if (error)
                error = null;

            // If value is null, or empty String just return ""
            // but treat it as an error for consistency.
            // Users will ignore it anyway.
            if (!value || (value is String && value == ""))
            {
                error = "Cannot convert an empty value";
                return "";
            }

            // Check to see if the input value must match the format pattern
            if (inputMustMatchPatternLength && String(value).length != countOccurrences(formatPattern, "#"))
            {
                error = "The input value length does not match the format pattern length.";
                return "";
            }

            // If the value is valid, format the string.
            var fStrLen:int = 0;
            var letter:String;
            var n:int;
            var i:int;
            var v:int;

            // Make sure the formatString is valid.
            n = formatPattern.length;
            for (i = 0; i < n; i++)
            {
                letter = formatPattern.charAt(i);
                if (letter == "#")
                {
                    fStrLen++;
                }
                else if (VALID_PATTERN_CHARACTERS.indexOf(letter) == -1)
                {
                    error = "You can only use the following symbols in the formatPattern: " + VALID_PATTERN_CHARACTERS;
                    return "";
                }
            }

            var returnString:String = "";
            var vStr:String = String(value).replace(".", "").split("").reverse().join("");
            var fArr:Array = formatPattern.split("").reverse();
            var fChar:String;

            // Format the string
            for (v = 0; v < vStr.length; v++)            {                   if (fArr.length > 0)
                {
                    do
                    {
                        fChar = fArr.shift();

                        if (fChar != "#")
                            returnString += fChar;

                    } while (fChar != "#" && fArr.length > 0);
                }

                returnString += vStr.charAt(v);
            }

            // Return the formatted string
            return returnString.split("").reverse().join("");
        }

        protected function countOccurrences(str:String, char:String):int
        {
            var count:int = 0;
            for (var i:int=0; i < str.length; i++)
            {
                if (str.charAt(i) == char)
                {
                    count++;
                }
            }
            return count;
        }
    }
}