Call function after remote call in Flex

I have a function in Flex which has three function in it.

public function update():void 
{
    A(); \\Dispatches a event with Remote Call
    B(); \\Dispatches another event with Remote Call
    C();
}

I wan't to call C() 开发者_Go百科after both A() and B() have returned from their call and set particular variables. How can i do that?

If you find yourself doing this often (esp. with more than 2 remote calls), you might want to write your own custom class that handles AsyncTokens from remote calls with a final result() function that is invoked when all remote calls end in success.

If not, since ActionScript is single-threaded, you can just use a local variable to track whether both calls have succeeded.

private var resultFromRemoteCallA:Object;
private var resultFromRemoteCallB:Object;

private function handleRemoteCallA(event:ResultEvent):void {
  resultFromRemoteCallA = event.result;
  C();
}

private function handleRemoteCallB(event:ResultEvent):void {
  resultFromRemoteCallB = event.result;
  C();
}

private function C():void {
  if (resultFromRemoteCallA && resultFromRemoteCallB) {
    // do some thing with the results.
  }
}

private function update():void {
  resultFromRemoteCallA = resultFromRemoteCallB = null;
  A(); B();
}

If you expect null values, you might want to use a boolean variable to track the invocation of the result handler instead.

EDIT: since the author indicated that the dispatch happens in another class, another way to do it would be to pass along a responder and attach it to the AsyncToken like so (in the callee):

private function dispatchRemoteCall(resultHandler:Function, faultHandler: Function): void {
  var resultToken: AsyncToken = remoteObject.foo('bar'); // remoteObject may or may not have a result/fault handler
  resultToken.addResponder(new mx.rpc.Responder(resultHandler, faultHandler));
}

Then, you can pass along listeners to be invoked when the remote call finishes (at which point you can choose to let the dispatching class store the result or handle it in the caller), like so:

private function update(): void {
  classA.dispatchRemoteCall(handleRemoteCallA, handleRemoteCallAFault);
}

If you find yourself doing this a lot, you may also want to look into having a framework do global event routing, like Parsley or Spring Actionscript.