Is it possible to get the type of uninitialized variable in Action Script 3?

The task was meant to be quite simple: I needed to initialize variable with new keyword dynamically, depending on it's type. For example:

public var object:Sprite;

...

object = new Sprite();

In this case type is Sprite, but it could be anything and a method which actually instantiates it with new, doesn't know with what type it was declared. Of course I cou开发者_StackOverflowld store type (or class name) in string variable and instantiate object with it. But I just wonder if I could get that type info from the object itself, 'cause it's declared in a class and logically thinking it's type info might be stored somewhere and be retrievable.

Yes, you can, but the variable must be public (or have accessor methods), and you need its name as a String:

Use describeType() to get an XML Description of your class, then get accessors and variables as XMLList, iterate until you find your variable's name, and get the class by calling getDefinitionByName(). Here's an example:

var className : String = "";
var type:XML = describeType (this);
var variables:XMLList = type..variable;
for each (var variable:XML in variables) {
    if (variable.@name == myVariableName) {
        className = variable.@type;
        break;
    }
}
if (className == "") {
    var accessors:XMLList = type..accessor;
    for each (var accessor:XML in accessors) {
        if (accessor.@name == myVariableName) {
            className = accessor.@type;
            break;
        }
    }
}
if (className=="") {
    trace ("no such variable");
    return;
}
var ClassReference : Class = getDefinitionByName( className.replace ("::", ".") ) as Class;
myVariable = new ClassReference( );

I can't figure out how to "reply" to an answer, otherwise I would add this to the current top answer.

If you have a list of known types that the object could be, you could test against those types using typeof.

switch(typeof unknownVar)
{
   case typeof Function:
       unknownVar = new Function();
       break;
   case typeof String:
       unknownVar = "Bruce Lee";
       break;
   case typeof Number:
       unknownVar = 3.14;
       break;
   default:
       trace(typeof unknownVar);  // This is not normally helpful...
}

In short no, you can't get the type of an uninitialised variable.

Sounds like this is kind of a factory pattern implementation. Your best bet is to pass a reference of the Class to the method

method:

public function create(class:Class) : void
{
   return new class();
}

calling code:

public var object:Sprite;

...

object = createObject(Sprite)