What is the best way to extract a diagonal from a matrix in Haskell?

I was asked to write a function that would extract the diagonal of a matrix stored as a list of lists. The first version was to extract the number by indexing the lists, but I soon concluded it isn't a good algorithm for Haskell and wrote another function:

getDiagonal :: (Num a) => [[a]] -> [a]
getDiagonal [[]]       = []
getDiagonal (xs:[])    = [head xs]
getDiagonal (x:xs)     = head x : getDiagonal (map tail xs)

Since I've only started learning Haskell I'm not sure if it's written in an idiomatic way or if it would perform well.

So my question is is there any better way to extract a diagonal from matrix stored in such a representation or if there isn't is there a better algorithm that could be constructed if the matrix was represented using higher order Haskell concepts, like algebraic types? Also is there any performance difference between deconstructing the list in pattern matching like so ((x:_):xs) or with the head function like shown above?

EDIT: Actually more of curious inquiry than a homework, they don't teach functional programming at technical universities here (whi开发者_如何学Pythonch is a pitty I think), but I'll leave the tag.

I think using indexing is OK, if you can assume that the argument is a square matrix. Getting diagonal with this representation is O(N²) anyway, since you have to traverse the lists.

diag x = zipWith (!!) x [0..]

You can simplify your original definition to:

mainDiagonal :: [[a]] -> [a]
mainDiagonal []     = []
mainDiagonal (x:xs) = head x : getDiagonal (map tail xs)

There isn't much wrong with using indexing for this, which lets you simplify it further to:

mainDiagonal xs = zipWith (!!) xs [0..]

Array-based representation

You can also represent matrixes using Data.Array indexed by (i,j). This lets you use the mathematical definition of the main diagonal almost verbatim:

import Data.Array

mainDiagonal :: (Ix i) => Array (i, i) e -> [e]
mainDiagonal xs = [ e | ((i,j),e) <- assocs xs, i == j ]

You can use this like:

-- n×n matrix helper
matrix n = listArray ((0,0),(n-1,n-1))

> mainDiagonal $ matrix 3 [1..]
[1,5,9]

Efficiency

The previous definition of mainDiagonal is still not efficient: it still needs O(N²) tests of i == j. Analogous to the zipWith version, it can be fixed and generalized as follows:

mainDiagonal xs = (xs !) `map` zip [n..n'] [m..m']
                      where ((n,m),(n',m')) = bounds xs

This version only indexes the array O(N) times. (As a bonus, it also works with rectangular matrices, and is independent of the indexing base.)

sdcwc has answered the original question. I'd like to note that representing the matrix as a list of lists is usually inefficient. Lists are good where the length is unknown, matrices are usually of the fixed size. You may consider using a flat associative list or map to build the matrix, and anything with constant element access time when you actually run calculations with this matrix. Data.Array is a good choice (see Piet's answer).

If you run numerical calculations in Haskell, you can use hmatrix package. It has its own matrix data type, Data.Packed.Matrix, and it has a takeDiag function to extract the diagonal.

Data.Packed.Matrix example

For example, if m is your matrix

ghci> let m = (3><3) [1..]
ghci> :t m
m :: Matrix Double
ghci> m
(3><3)
 [ 1.0, 2.0, 3.0
 , 4.0, 5.0, 6.0
 , 7.0, 8.0, 9.0 ]

then you can extract its diagonal like this:

ghci> takeDiag m
3 |> [1.0,5.0,9.0]

Just complementing Delport's answer a little bit, if performance is not that relevant and you choose this approach:

diagonal :: [[a]] -> [a]
diagonal [] = []
diagonal (mHead:mTail) = head mHead:diagonal (map tail mTail)

It should be noted that this function can only be used with matrices you know are square, due to head and tail usage.

For n X m matrices you can either implement the function to ignore extra values, making [[1,2,3], [4,5,6]] return [1,5]:

diagonal [] = []
diagonal ([]:_) = []
diagonal ((rHead:_):mTail) = rHead:diagonal (map tail mTail)

Or implement a version that will throw an error when your matrix is not square:

diagonal [] = []
diagonal ([]:_) = error "not a square matrix"
diagonal [x:y:z] = error "not a square matrix"
diagonal ((rHead:_):mTail) = rHead:diagonal (map tail mTail)

For both answers, it should be noted that they might still throw 'unexpected' errors if your 'list of lists' is not a matrix/not uniform ([[1,2], [1]]) due to the map tail mTail call.