How to iterate through range of Dates?

In my script, I need to iterate through a ran开发者_JAVA百科ge of dates given the start date and end date. How can I do this in Perl?

Use DateTime module. Here is a simple example which lists the ten previous days:

use 5.012;
use warnings;
use DateTime;

my $end = DateTime->now;
my $day = $end->clone->subtract( days => 10 );  # ten days ago

while ($day < $end) {
    say $day;
    $day->add( days => 1 );   # move along to next day
}

Update (after seeing your comment/update):

To parse in a date string then look at the DateTime::Format on modules CPAN.

Here is an example using DateTime::Format::DateParse which does parse YYYY/MM/DD:

use DateTime::Format::DateParse;
my $d = DateTime::Format::DateParse->parse_datetime( '2010/06/23' );

One easy approach is to use the Date::Simple module, which makes use of operator-overloading:

use strict;
use warnings;
use Date::Simple;

my $date    = Date::Simple->new ( '2010-01-01' );  # Stores Date::Simple object
my $endDate = Date::Simple->today;                 # Today's date

while ( ++$date < $endDate ) {

    print ( $date - $endDate ) , "day",
          ( ( $date-$endDate) == 1 ? '' : 's' ), " ago\n";
}

use DateTime::Format::Strptime qw();
my $start = DateTime::Format::Strptime->new(pattern => '%Y/%m/%d')->parse_datetime('2010/08/16');
my $end   = DateTime::Format::Strptime->new(pattern => '%Y/%m/%d')->parse_datetime('2010/11/24');

while ($start < $end) {
    $start->add(days => 1);
    say $start->ymd('/');
}

I like to use the fact that strftime will normalize the date for me:

#!/usr/bin/perl

use strict;
use warnings;

use POSIX qw/strftime/;

my $start = "2010/08/16";
my $end   = "2010/09/16";

my @time        = (0, 0, 0);
my ($y, $m, $d) = split "/", $start;
$y -= 1900;
$m--;
my $offset      = 0;

while ((my $date = strftime "%Y/%m/%d", @time, $d + $offset, $m, $y) le $end) { 
    print "$date\n";
} continue {
    $offset++;
}

You can try Date::Calc::Iterator

  # This puts all the dates from Dec 1, 2003 to Dec 10, 2003 in @dates1
  # @dates1 will contain ([2003,12,1],[2003,12,2] ... [2003,12,10]) ;
  my $i1 = Date::Calc::Iterator->new(from => [2003,12,1], to => [2003,12,10]) ;
  my @dates1 ;
  push @dates1,$_ while $_ = $i1->next ;

If installing extra perl modules is not preferable, one can use this approach, based on a core perl library POSIX:

#!/usr/bin/perl

use strict;
use warnings;
use POSIX qw(strftime);

# CREATE CALENDAR
my @Calendar = ();
my $years = 3;
my @Now = localtime(); # An array of 9 date-time parameters.

for my $count ( 0 .. ( 365 * $years ) ) {
    # If date is January 1st, manual shift to December 31st is needed,
    # because days ([yday][2]) are counted from January 31st and never shift back one year.
    if( $Now[4] == 0 && $Now[3] == 1 ) {
        unshift @Calendar, strftime( "%Y-%m-%d", @Now );
        $Now[5] --; # Reduce by one the sixth array element #5 - year.
        $Now[4] = 11; # Set fifth array element № 4 - to December.
        $Now[3] = 31; # Set fourth array element № 3 - to 31st.
    } else {
        unshift @Calendar, strftime( "%Y-%m-%d", @Now );
        $Now[3] --;
    }
}

# Print out.
my $size = @Calendar;
for (my $i = 0; $i < $size; $i++) {
    print $Calendar[$i]."\n";
}

Perl has a rich array of time and date manipulation modules, as seen here:

http://datetime.perl.org/?Modules

And there are some examples of date and time problems there as well.

With Perl, there's always more than one way to do it.