SPARQL Negation: All foaf:Agents which aren't foaf:Persons

I am trying to write a SPARQL query which should give me all foaf:Agents which aren't foaf:Persons.

I can't see a way to apply 开发者_如何学Cthis OPTIONAL/BOUND construct to this problem, because all the properties like rdfs:subClassOf and rdf:type are transitive and reflexive.

I tried this:

SELECT * WHERE { 
?x rdf:type foaf:Agent 
OPTIONAL { ?y rdf:type foaf:Person } 
FILTER ( !BOUND(?y) ) }

But rdf:type seems to be transitive, at least with JENA/ARQ/SDB.

The reason this isn't working is because you have two separate variable bindings (?x and ?y) which are unrelated in your query. So ?x must be bound to appear in the result set (which is what you want), but if ?y is unbound, you have not learned anything new about ?x.

Update: In an ideal query, there would be no need for ?y at all; you could test the incoming/outgoing edegs of ?x directly. This is difficult (impossible?) to do in SPARQL 1.0 when you want to check if an edge does not exist on a given variable binding. However, SPARQL 1.1 will provide support for negation:

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#> 
PREFIX foaf: <http://xmlns.com/foaf/0.1/> 

SELECT ?agent
WHERE 
{
    ?agent rdf:type foaf:Agent .
    FILTER NOT EXISTS { ?agent rdf:type foaf:Person . }
}

@Kingsley Idehen's approach (using third-party SPARQL extensions) should help you solve the problem in the short run.

To do this in SPARQL 1.0, you'd have to write:

SELECT * WHERE { 
     ?x rdf:type foaf:Agent 
     OPTIONAL { ?y rdf:type foaf:Person . FILTER (?x = ?y) . } 
     FILTER ( !BOUND(?y) ) 
}

As Phil M says, SPARQL 1.1 will introduce new syntax to make this much more straightforward to write.

Here's the (draft) SPARQL 1.1 spec for negation: http://www.w3.org/TR/sparql11-query/#negation

Via Virtuoso SPARQL Extensions endpoint for verification http://lod.openlinksw.com/sparql (LOD Cloud Cache Instance)

SELECT distinct ?x ?o 
WHERE { 
?x a foaf:Agent .
?x ?p ?o.
filter (!bif:exists ((select (1) where { ?x a foaf:Person } ))) 
} 
limit 10

DESCRIBE ?x 
WHERE { 
?x a foaf:Agent .
filter (!bif:exists ((select (1) where { ?x a foaf:Person } ))) 
} 
limit 200 

The following now works, courtesy of SPARQL 1.1:

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#> 
PREFIX foaf: <http://xmlns.com/foaf/0.1/> 
SELECT DISTINCT COUNT(?agent)
WHERE 
{
    ?agent rdf:type foaf:Agent .
    FILTER (NOT EXISTS { ?agent rdf:type foaf:Person . })
}

Live example links:

1. Query Solution

2. Query Definition