Complex XSL Transformation

I am still a beginner with XSLT but I am having a difficult task in hand.

I have a non-xml file which needs to be transformed. The format of the file is a s follows:

type1
type1line1
type1line2
type1line3
type2
type2line1
type2line2
type3
type3line1
type3line2

types (type1, type2, ...) are specified using certain codes which don't have a specific order. Each type has multiple line underneath.

So, I need to transform this f开发者_运维问答ile but the problem is that for each type I have to do a different transformation for each of it's underlying lines.

Now, I can read the string line by line and determine that a new type has begun but I don't know how to set a flag (indicating the type) to use it in the underlying lines.

Here is what I have right now:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema" version="2.0">  
  <xsl:param name="testString" as="xs:string">
  type1
  line1
  line2
  type1
  line1 
  </xsl:param>  
  <xsl:template match="/"> 
    <xsl:call-template name="main"> 
      <xsl:with-param name="testString" select="$testString"/> 
    </xsl:call-template> 
  </xsl:template>  

  <xsl:template name="main"> 
    <xsl:param name="testString"/>
    <xsl:variable name="iniFile" select="$testString"/>  
    <config> 
      <xsl:analyze-string select="$iniFile" regex="\n"> 
        <xsl:non-matching-substring> 
          <item> 
            <xsl:choose> 
              <xsl:when test="starts-with(., 'type1')">
   <!-- do a specific transformation-->     
              </xsl:when> 
              <xsl:when test="starts-with(., 'type2')">
   <!-- do another transformation-->      
              </xsl:when>
            </xsl:choose> 
          </item> 
        </xsl:non-matching-substring> 
      </xsl:analyze-string> 
    </config> 
  </xsl:template> 
</xsl:stylesheet>

Any idea about how to solve the problem.

I think XSLT 2.1 will allow you to use its powerful stuff like for-each-group on sequences of atomic values like strings but with XSLT 2.0 you have such powerful features only for sequences of nodes so my first step when using XSLT 2.0 with plain string data I want to process/group is to create elements. So you could tokenize your data, wrap each token into some element and then use for-each-group group-starting-with to process each group starting with some pattern like '^type[0-9]+$'. You haven't really told us what you want to with the data once you have identified a group so take the following as an example you could adapt:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="2.0"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  exclude-result-prefixes="xs">

  <xsl:output method="xml" indent="yes"/>

  <xsl:param name="input" as="xs:string">type1
type1line1
type1line2
type1line3
type2
type2line1
type2line2
type3
type3line1
type3line2</xsl:param>

   <xsl:template name="main">
     <xsl:variable name="lines" as="element(item)*">
       <xsl:for-each select="tokenize($input, '\n')">
         <item><xsl:value-of select="."/></item>
       </xsl:for-each>
     </xsl:variable>
     <xsl:for-each-group select="$lines" group-starting-with="item[matches(., '^type[0-9]+$')]">
       <xsl:choose>
         <xsl:when test=". = 'type1'">
           <xsl:apply-templates select="current-group() except ." mode="m1"/>
         </xsl:when>
         <xsl:when test=". = 'type2'">
           <xsl:apply-templates select="current-group() except ." mode="m2"/>
         </xsl:when>
         <xsl:when test=". = 'type3'">
           <xsl:apply-templates select="current-group() except ." mode="m3"/>
         </xsl:when>
       </xsl:choose>
     </xsl:for-each-group>
   </xsl:template>

   <xsl:template match="item" mode="m1">
     <foo>
       <xsl:value-of select="."/>
     </foo>
   </xsl:template>

   <xsl:template match="item" mode="m2">
     <bar>
       <xsl:value-of select="."/>
     </bar>
   </xsl:template>

   <xsl:template match="item" mode="m3">
     <baz>
       <xsl:value-of select="."/>
     </baz>
   </xsl:template>

</xsl:stylesheet>

When applied with Saxon 9 (command line options -it:main -xsl:sheet.xsl) the result is

<foo>type1line1</foo>
<foo>type1line2</foo>
<foo>type1line3</foo>
<bar>type2line1</bar>
<bar>type2line2</bar>
<baz>type3line1</baz>
<baz>type3line2</baz>