Capitalize every word in actionScript using a regular expression

I'm trying to do initial caps in actionScript without loops but I'm stuck. I wanted to select the first letter or every word then apply uppercase on that letter. Well I got the selection part right, but at a dead end right now, any ideas? I was tr开发者_如何学Goying to do this without loops and cutting up strings.

// replaces with x since I can't figure out how to replace with
// the found result as uppercase
public function initialcaps():void 
{
    var pattern:RegExp=/\b[a-z]/g;
    var myString:String="yes that is my dog dancing on the stage";
    var nuString:String=myString.replace(pattern,"x");
    trace(nuString);
}

You can also use this to avoid the compiler warnings.

myString.replace(pattern, function():String
            {
                return String(arguments[0]).toUpperCase();
            });

Try to use a function that returns the uppercase letter:

myString.replace(pattern, function($0){return $0.toUpperCase();})

This works at least in JavaScript.

Just thought I'd throw them two cents in for strings that may be all caps

var pattern:RegExp = /\b[a-zA-Z]/g;
myString = myString.toLowerCase().replace(pattern, function($0){return $0.toUpperCase();});

This answer does not throw any kind of compiler errors under strict and I wanted it to be a little more robust, handling edge cases like hyphens (ignore them), underscores (treat them like spaces) and other special non-word characters such as slashes or dots.

It's really important to note the /g switch at the end of the regular expression. Without it, the rest of the function is pretty useless, because it will only address the first word, and not any subsequent ones.

for each ( var myText:String in ["this is your life", "Test-it", "this/that/the other thing", "welcome to the t.dot", "MC_special_button_04", "022s33FDs"] ){
    var upperCaseEveryWord:String = myText.replace( /(\w)([-a-zA-Z0-9]*_?)/g, function( match:String, ... args ):String { return args[0].toUpperCase() + args[1]  } );
    trace( upperCaseEveryWord );
}

Output:

This Is Your Life
Test-it
This/That/The Other Thing
Welcome To The T.Dot
MC_Special_Button_04
022s33FDs

For the copy-and-paste artists, here's a ready-to-roll function:

public function upperCaseEveryWord( input:String ):String {
    return input.replace( /(\w)([-a-zA-Z0-9]*_?)/g, function( match:String, ... args ):String { return args[0].toUpperCase() + args[1]  } );
}