Matchit not working

I am using Macvim 7.3 snapshot 57. I can't seem to get matchit to work in any of my files.

I press % on an opening tag. It doesn't take me to the closing tag...

My vimrc file:

" Pathogen settings
call pathogen#runtime_append_all_bundles()
call pathogen#helptags()

set nocompatible

set number
set ruler
set cursorline
syntax on

" Disable all blinking
set guicursor+=a:blinkon0

" Whitespace stuff
set nowrap
set tabstop=2
set shiftwidth=2
set expandtab
set cindent
set smartindent
set autoindent
set list listchars=tab:\ \ ,trail:·

" Searching
set hlsearch
set incsearch
set ignorecase
set smartcase

" Status bar
set laststatus=2

" Start without the toolbar
set guioptions-=T

" Default gui color scheme
" "color default
" color molokai
color railscasts+

" Command-/ to toggle comments
map <D-/> :TComment<CR>j

" Remember last location in file
if has("autocmd")
  au BufReadPost * if line("'\"") > 0 && line("'\"") <= line("$")
    \| exe "normal g'\"" | endif
endif

" Thorfile, Rakefile and Gemfile are Ruby
au BufRead,BufNewFile {Gemfile,Rakefile,Thorfile,config.ru} set ft=ruby

" Open split buffers below instead of above current buffer
set splitbelow

" Session options
let g:session_autoload = 1
let g:session_autosave = 1

" Buffer navigation
map <C-K> <C-W><C-K>
map <C-J> <C-W><C-W>
map <C-H> <C-W><C-H>
map <C-L> <C-W><C-L>

" Rails navigation options
nmap <leader>rc :Rcontroller 
nmap <leader>rv :Rview 
nmap <leader>rm :Rmodel 

" Tab completion
" Also needed for better Rails navigation auto-completion
set wildmode=list:longest,list:full

" Open up side panel left (NERDTree) and right(Tagbar)
" nmap <leader>\ :NERDTreeToggle<CR> :TagbarToggle<CR>
nmap <leader>\ :call ToggleNERDTreeAndTagbar()<CR>

" Allow single click for NERDTree
let NERDTreeMouseMode = 3
let g:NERDTreeWinSize = 30
" autocmd VimEnter * NERDTree

" Tagbar options
let tagbar_singleclick = 1
let g:tagbar_sort = 0
let g:tagbar_width = 30
" autocmd VimEnter * nested TagbarOpen

" The Janus plugin sets this to noequ开发者_JAVA百科alalways for the Zoominfo plugin
" However, we want to set this to equalalways instead, since we want to
" have equal window height when a new window is opened. i.e. via ctrl+w+s
set equalalways

" Matchit already installed in newer versions of vim.
" Don't need to add this onto pathogen bundle folder. We only need
" to configure it.
" Configure matchit so that it goes from opening tag to closing tag
au FileType html,eruby,rb,css,js,xml runtime! macros/matchit.vim

" Set backup and swp dir. Don't forget to clear tmp dir out once in a while
set backupdir=~/.vim/tmp/backup
set directory=~/.vim/tmp/swp

" Detect if a tab was closed, and ensure that height of main window fills the screen (100% height)
au TabEnter * let &lines = 100

" <leader>\ to open or close NERDTree and Tagbar, under the following conditions:
" 1) Only close both if NERDTree and Tagbar are both opened
" 2) Open both if NERDTree and Tagbar are closed OR if one is already opened
function! ToggleNERDTreeAndTagbar()
  let w:jumpbacktohere = 1

  " Detect which plugins are open
  if exists('t:NERDTreeBufName')
      let nerdtree_open = bufwinnr(t:NERDTreeBufName) != -1
  else
      let nerdtree_open = 0
  endif
  let tagbar_open = bufwinnr('__Tagbar__') != -1

  " Perform the appropriate action
  if nerdtree_open && tagbar_open
      NERDTreeClose
      TagbarClose
  elseif nerdtree_open
      TagbarOpen
  elseif tagbar_open
      NERDTree
  else
      NERDTree
      TagbarOpen
  endif

  " Jump back to the original window
  for window in range(1, winnr('$'))
    execute window . 'wincmd w'
    if exists('w:jumpbacktohere')
      unlet w:jumpbacktohere
      break
    endif
  endfor
endfunction

Since Vim comes shipped with matchit plugin, all I needed to do was activate it:

vim ~/.vimrc

Then add the following into your .vimrc:

set nocompatible
filetype plugin on
runtime macros/matchit.vim

This line

runtime macros/matchit.vim

is the standard way of activating matchit and it works on all my machines.

Does matchit work after you type

:runtime macros/matchit.vim

in normal mode ?

The page of the matchit plugin says:

Make sure you have a line like

:filetype plugin on

in your vimrc file. This enables filetype plugins, many of which tell matchit.vim which matching pairs to use.

FYI: in vim 8 runtime macros/matchit.vim becomes packadd! matchit.

I started having the same issue after I updated some of my vim plugings to the latest version for 7.3.

But when I run

:MatchDebug

it fixes the issue for me.

I had a problem with matchit finding the correct matching brace in C++/C when there were commented braces. The following steps, taken from this forum post written by this guy, solved it for me and also pretty much explained the way the whole thing works:

1. Create the folder ~/.vim/plugin if it is not already there:

   mkdir ~/.vim/plugin 
   

2. Create a file with the name ~/.vim/plugin/matchit.vim :

   vi ~/.vim/plugin/matchit.vim 
   

   and the following contents:

   runtime macros/matchit.vim 
   

3. Create the directory ~/.vim/doc if it is not already there:

   mkdir ~/.vim/doc
   

4. Copy /usr/share/vim/vim73/macros/matchit.txt to ~/.vim/doc/ :

   cp /usr/share/vim/vim73/macros/matchit.txt ~/.vim/doc/
   

5. Open vi

   vi
   

   and execute the following in it:

   :helptags ~/.vim/doc 
   

6. Make sure that your ~/.vimrc includes one of the following:

   source $VIMRUNTIME/vimrc_example.vim 
   

   or

   runtime vimrc_example.vim 
   

   or

   filetype plugin on 
   

   or

   filetype plugin indent on 
   

7. Add the following autocommand in your vimrc:

   " make matchit work on C-like filetypes 
   " c and cpp are already handled by their ftplugin 
   au Filetype css,javascript 
           \ let b:match_words = &matchpairs 
   

8. Restart Vim.

I've had similar problem. I've tried runtime macros/matchit.vim with VIM-provided script and it didn't work. So I've downloaded this script in version 1.13.2 from http://www.vim.org/scripts/script.php?script_id=39, unzipped it into ~/vimfiles and it works!