indexOf on an array populated by xml

i have a strange issue.

When trying to do indexOf on a "static" array, it works, doing the same thing on an array populated with xml, i always get the result = -1

Static Way

var myarray:Array = new Array("Pub Pepsi","Shadow E-Bike","Icon Air Craft","Test","La page 4","La page 5","La page 6","La page 7");
var myresult:* = myarray.indexOf("Icon Air Craft");
trace(myresult);
// I get 2 as result so it works

Dynamic Way (from xml)

var Monthpath:String = "juin";
var XMLpathUrl:String = "http://www.omagazine.fr/editions/2011/" + Monthpath + "/obook_content.xml.php";
var xml:XML;
var xmlLoader:URLLoader = new URLLoader();
var myarray:Array = new Array();

xmlLoader.addEventListener(Event.COMPLETE, xmlLoaded);

function xmlLoaded(event:Event):void
{
    xmlLoader.removeEventListener(Event.COMPLETE, xmlLoaded);
    xmlLoader.removeEventListener(IOErrorEvent.IO_ERROR, xmlError);

    xml = new XML(event.target.data);

    for (var i in xml.pages.page)
    {
        myarray.push(xml.pages.page[i].@ga);
    }

    var myres开发者_StackOverflowult:* = myarray.indexOf("Icon Air Craft");
    trace(myresult);
    //-------------------------------------
    // I get -1 as result!!!! Why????
    //-------------------------------------
}

xmlLoader.addEventListener(IOErrorEvent.IO_ERROR, xmlError);

function xmlError(event:IOError):void
{
    trace("Error");
}
xmlLoader.load(new URLRequest(XMLpathUrl));

You are pushing an XML object to your array, not a string. This should work if you use .toString() on the attribute.

for (var i in xml.pages.page)
{
    myarray.push(xml.pages.page[i].@ga.toString());
}

var myresult:* = myarray.indexOf("Icon Air Craft");
trace(myresult);