perl equal strings returns 0 even if they are equal

Perl is continuing to surprise me. I have a code which takes an input from the command line and checks if it is in a file. I hav开发者_运维问答e a file like this:

ls

date

pwd

touch

rm

First i read this file as

open(MYDATA,"filename") or die "Can not open file\n";
@commandlist = <MYDATA>;
chomp @commandlist;
close MYDATA;

the argument is in $commandname variable. To check if it is correct i printed to screen.

print $commandname."\n";

it works well. then i write the code.

$count = @commandlist;
for($i=0;$i < $count;$i++)
{
    print $commandname;
    print $commandlist[$i];
    print "\n";
    if($commandname eq $commandlist[$i])
    {
        print "equal\n";
    }
}

and it does not print 'equal'. but it should do becaues $commandname variable has the value 'ls' which is in the file. i also print the value of $commandname and $commandlist[$i] to see if "visibly" they are equal and i get the output:

ls
lsls
lsdate
lspwd
lstouch
lsrm

here i see that they got the same value but why never eq operator evaluates to zero. Additionally to get this task done, I have tried various methods all of which come to be useless like making a hash from the array and using exists. I am struggling for this seemingly easy problem for a day but i just dont get it. Thanks in advance

EDIT: when i change the above loop as below

$count = @commandlist;
for($i=0;$i < $count;$i++)
{
    print $commandlist[$i];
    print $commandname;
    print "\n";
    if($commandname eq $commandlist[$i])
    {
        print "equal\n";
    }
}

I got an output like.

ls
ls
lste
lsd
lsuch
ls

it seems like for some reason it overwrites some characters.

EDIT:

my whole script is like:

#reading file code, i posted above
while(<>)
chomp($_);
$commandname = $_;
if($commandname eq "start"){
##something here
} elsif ($commandname eq "machines"){
##something here
} else {

    $count = @commandlist;
    for($i=0;$i < $count;$i++)
    {
        print $commandlist[$i];
        print $commandname;
        print "\n";
        if($commandname eq $commandlist[$i])
        {
            print "equal\n";
        }
    }

}

A bit change in the code would result in what you are looking for, "chomp" the string from array before you put it for comparison. Here it is

chomp $commandlist[$i];

if($commandname eq $commandlist[$i])
{
    print "equal\n";
}

EDIT: as per perldoc chomp when you are chomping a list you should parenthesis. So, in your case ... instead simply saying

chomp @commandlist 

make it like

chomp(@commandlist)

FINAL EDIT: I tried this and worked fine. Give it a try

$commandname = $ARGV[0];

open(MYDATA,"chk.txt") or die "Can not open file\n"; 
@commandlist = <MYDATA>; 
chomp(@commandlist);
close MYDATA; 

print $commandname."\n"; 

$count = @commandlist;
print $commandname; 
for($i=0;$i < $count;$i++) 
 {

 print $commandlist[$i]; 
 print "\n"; 
 if($commandname eq $commandlist[$i]) 
 {   
  print "equal\n";   
 } 
 }

The overwritting indicates the presence of a CR. The lines end with CR LF, but you only remove the LF with chomp. Change

while (<>) {
    chomp($_)

to

while (<>) {
    s/\s+\z//;

You might consider restructuring your code as:

my $path='filename';
my $match='ls';

part 1 - read the file

open(my $fh, '<', $path) or die "failed to open $path: $!";
my @commandlist=<$fh>;
chomp @commandlist;  
# or you can combine these lines as: 
#    chomp(my @commandlist=<$fh>);
# because chomp operates on the array itself rather than making a copy.
close($fh);

or

use File::Slurp qw/ read_file /; 
# see http://search.cpan.org/dist/File-Slurp/lib/File/Slurp.pm

my @commandlist=read_file($path);  # result is pre-chomped!

part 2 - check for a match

foreach my $command (@commandlist) {
  print "$match equals $command\n" if $match eq $command;
}

One important consideration is that each line in your file must contain only the command name and cannot begin or end with any spaces or tabs. To compensate for possible leading or trailing whitespace, try:

foreach my $command (@commandlist) {
  $command=~s/^\s+|\s+$//g; # strip leading or trailing whitespace
  print "$match equals $command\n" if $match eq $command;
}

And finally, always start your Perl script with a Perl developer's bestest friends:

use strict;
use warnings;

which will catch most (if not all) errors caused by sloppy programming practice. (We all suffer from this!)