How to take a browsed text file and put it into a list box VBA

So i'm new to using access/VBA and i'm having trouble getting this to work.

Private Sub Get_File_Click()

    Dim fdlg As Office.FileDialog
    Dim pipe_file As Variant
    Dim FileName As String
    Dim file As String
    Dim fn As Integer

    ' Clear contents of listboxes and textboxes. '
    Me.OrigFile.RowSource = ""
    Me.ConvertFile.RowSource = ""
    Me.FileName = ""

    ' Set up the File dialog box. '
    Set fdlg = Application.FileDialog(msoFileDialogFilePicker)
    With fdlg
        .AllowMultiSelect = False

        ' Set the title of the dialog box. '
        .Title = "Select pipe delimited file" 

        ' Clear out the current filters, and then add your own. '
        .Filters.Clear
        .Filters.Add "Text Files", "*.txt"


        ' Show the dialog box. If the .Show method returns True, the '
        ' user picked a file. If the .Show method returns            '
        ' False, the user clicked Cancel.                            '
        If .Show = True Then
            file = fdlg
            fn = FreeFile
            Open file For Input As #fn
            Do While Not EOF(fn)
                Line Input #fn, pipe_file
                Me.OrigFile.AddItem pipe_file
            Loop
        Else
      开发者_JS百科      MsgBox "You clicked Cancel in the file dialog box."
        End If
    End With
End Sub

This is what i have so far. origFile is the listbox i'm trying to put the textfile into. Any help is appreciated Thanks

Comments added Inline:

Private Sub Get_File_Click()

    Dim fdlg As Office.FileDialog
    Dim pipe_file As Variant
    'Why two vars named 'FileName' and 'file'?  Since they are both string, assuming just one of these will do.
    Dim FileName As String
    'Dim file As String
    Dim fn As Integer
    'Need variant variable to get file name
    Dim varFile As Variant

    Me.OrigFile.RowSource = ""
    Me.ConvertFile.RowSource = ""

    'Don't use ME here.  Unless you have an object named FileName (which I'm not sure why you would in this case)
    'Me.FileName = ""
    FileName = ""

    Set fdlg = Application.FileDialog(msoFileDialogFilePicker)
    With fdlg
        .AllowMultiSelect = False
        .Title = "Select pipe delimited file"
        .Filters.Clear
        .Filters.Add "Text Files", "*.txt"

        If .Show = True Then
            'Never used this code before but this is how you get the file name:
            'Seems lame to have three lines of code to get one file name, but I guess this is the way this control works
            For Each varFile In .SelectedItems
                FileName = varFile
            Next varFile

            'The invalid code below was causing the error and it is no longer necessary.
            'However, also wanted to point out that you are already in a With block for fldg so the fdlg object is not required

            'FileName = fdlg.SelectedItems

            fn = FreeFile 'FreeFile = Good!

            'Commented out the line below because file is not used

            'Open file For Input As #fn
            Open FileName For Input As #fn
            Do While Not EOF(fn)
                Line Input #fn, pipe_file
                Me.OrigFile.AddItem pipe_file
            Loop

            'Make sure to close the file too!
            Close #fn
        Else
            MsgBox "You clicked Cancel in the file dialog box."
        End If
    End With
End Sub

Also, one final tip, make sure you have the following line of code declared at the top of your modules:

Option Explicit

This will prevent you from accidentally typing in the name of a variable incorrectly.

You can have the VBA project add this line by default if you click "Tools/Options" and then select "Require Variable Declaration" in the Editor tab.

I think your problem is the line

file = fdlg

should be

file = fdlg.SelectedItems(1)