Can mousePressed be defined within a class?

I am trying to create a class called InputManager to handle mouse events. This requires that mousePressed be contained within the InputManager class.

like so

class InputManager{
    void 开发者_JAVA百科mousePressed(){
       print(hit);
    }
}

problem is, that doesn't work. mousePressed() only seems to work when it's outside the class.

How can I get these functions nicely contained in a class?

Try this:

in main sketch:

InputManager im;

void setup() {
im = new InputManager(this);
registerMethod("mouseEvent", im);

}

in InputManager Class:

class InputManager {
    void mousePressed(MouseEvent e) { 
         // mousepressed handling code here... 
    }

    void mouseEvent(MouseEvent e) {
       switch(e.getAction()) {
          case (MouseEvent.PRESS) : 
               mousePressed();
               break;
          case (MouseEvent.CLICK) :
               mouseClicked();
               break;
          // other mouse events cases here...
       }
    }
}

Once you registered InputManger mouseEvent in PApplet you don't need to call it and it will be called each loop at the end of draw().

Most certainly, but you are responsible for ensuring it gets called:

interface P5EventClass {
  void mousePressed();
  void mouseMoved();
  // ...
}

class InputManager implements P5EventClass {
  // we MUST implement mousePressed, and any other interface method
  void mousePressed() {
    // do things here
  }
}

// we're going to hand off all events to things in this list
ArrayList<P5EventClass> eventlisteners = new ArrayList<P5EventClass>();

void setup() {
  // bind at least one input manager, but maybe more later on.
  eventlisteners.add(new InputManager());
}

void draw() {
  // ...
}

void mousePressed() {
  // instead of handling input globally, we let
  // the event handling obejct(s) take care of it
  for(P5EventClass p5ec: eventlisteners) {
   p5ec.mousePressed();
  }
}

I would personally make it a bit tighter by also passing the event variables explicitly, so "void mousePressed(int x, int y);" in the interface and then calling "p5ec.mousePressed(mouseX, mouseY);" in the sketch body, simply because relying on globals rather than local variables makes your code prone to concurrency bugs.

The easiest way to do so would be:

class InputManager{
    void mousePressed(){
       print(hit);
    }
}

InputManager im = new InputManager();

void setup() {
   // ...
}

void draw() {
   // ...
}

void mousePressed() {
   im.mousePressed();
}

This should solve any problems you were having with variable scoping in your class.

Note: In the class, it doesn't even have to be named mousePressed, you can name it anything you wish, as long as you call it inside of the main mousePressed method.