what does this Perl foreach do?

I am stuck开发者_如何学运维 while understanding what this foreach does, I am new to perl programming

-e && print ("$_\n") foreach $base_name, "build/$base_name";

here build is directory. Thanks

Not very pretty code somebody left you with there. :(

Either of

for ($basename, "build/$basename") { say if -e }

or

for my $file ($basename, "build/$basename") {
     say $file if -e $file;
}

would be clearer.

Checks whether the file exists, and if it does,prints its name.

It can be written in a clearer way.

It iterates over $base_name and then build/$base_name while the file name is in $base_name

it is essentially the same as:

foreach( $base_name, "build/$base_name" ){
  if( -e ){ 
    print ("$_\n");
  }
}

I hope whoever wrote that isn't prolific.

How many ways to do the same thing in a clearer fashion?

grep

grep filters a list and removes anything that returns false for the the check condition. The current value under consideration is set to $_, so it is very convenient to use file test operators.

Since say and print both handle lists of strings well, it makes sense to filter output before passing it to them.

say grep -e, $base_name, "build/$base_name";

On older perls without say, map is sometimes used to apply newlines to the output before it is printed.

print map "$_\n", grep -e, $base_name, "build/$base_name";

for

Here we safely use a statement modifier if. IMHO, statement modifier forms can be very handy as long as the LHS is kept very simple.

for my $dir ( $base_name, "build/$base_name" ) { print "$dir\n" if -e $dir; }

punctuation

Still ugly as sin, but breaking up the line and using some extra parens helps identify what is being looped over and separate it from the looping code.

-e && print("$_\n")
    foreach( $base_name, "build/$base_name" );

It's better, but please don't do this. If you want to do ($foo if $bar) for @baz; DON"T. Use a full sized block. I can count one time in my life where it felt OK to use a $bar and $foo for @baz construct like this one--and it was probably wrong to use it.

sub

The OP's mystery code is nicer if it is merely wrapped in a sub with a good name.

I'll write this in the ugliest way I know how:

sub print_existing_files { -e && print ("$_\n") foreach @_; }

The body of the sub remains a puzzle, but at least there's some kind of clue in the name.

Conclusion

I'm sure I left out many variations on how this could be done (I don't have anything that uses until, and damn near anything that isn't intentionally obfuscated would be clearer). But that is beside the point.

The point of this is really to say that in any language there are many ways to achieve any given task. It is, therefore, important that each programmer who works on a system remain mindful of those who follow.

Code exists to serve two purposes: to communicate with future programmers and to instruct the computer how to operate--in that order.