How do I convert strings to title case in OpenEdge ABL / Progress 4GL?

How do I convert a string to title case in OpenEdge ABL (aka Progress 4GL)?

I know I can get upper case with CAPS(), and lower case with LC(), but I can't find the title case (sometimes called proper case) function.

Examples:

Input           Output
------------    ------------
hello world!    Hello World!
HELLO WORLD!    Hello World!

function titleWord returns character ( input inString as character ):
  return caps( substring( inString, 1, 1 )) + lc( substring( inString, 2 )).
end.

function titleCase returns character ( input inString as character ):

  define variable i as integer no-undo.
  define variable n as integer no-undo.

  define variable outString as character no-undo.

  n = num-entries( inString, " " ).
  do i = 1 to n:
    outString =
      outString +
      ( if i > 1 and i <= n then " " else "" ) +
      titleWord( entry( i, inString, " " ))
    .
  end.

  return outString.

end.

display
  titleCase( "the quick brown fox JUMPED over the lazy dog!" ) format "x(60)"
.

I think the order of one of those statements above is incorrect -

You'll be adding an extra " " at the beginning of the string! Also need to change the <= to < or you'll be tacking an extra " " into your return string.

It should be:

n = num-entries( inString, " " ).
  do i = 1 to n:
    outString =
      outString +
      titleWord( entry( i, inString, " " )) +
      ( if i < n then " " else "" ) +
    .
  end.

At least that's what I -think- it should be...

-Me

I was playing around with this a while back, and besides a solution similar to Tom's, I came up with two variations.

One of the problems I had was that not all words are separated by space, such as Run-Time and Read/Write, so I wrote this version to use any non-alphabetic characters as separators.

I also wanted to count diacritics and accented characters as alphabetic, so it became a little complicated. To solve the problem I create two versions of the title, one upper and one lower case. Where the two strings are the same, it's a non-alphabetic character, where they are different, it's alphabetical. Titles are usually very short, so this method is not as inefficient as might seem at first.

FUNCTION TitleCase2 RETURNS CHARACTER
  ( pcText AS CHARACTER ) :
/*------------------------------------------------------------------------------
  Purpose: Converts a string to Title Case.  
    Notes: This version takes all non-alphabetic characters as word seperators
           at the expense of a little speed. This affects things like
           D'Arby vs D'arby or Week-End vs Week-end.
------------------------------------------------------------------------------*/

  DEFINE VARIABLE cUText AS CHARACTER   NO-UNDO CASE-SENSITIVE.
  DEFINE VARIABLE cLText AS CHARACTER   NO-UNDO CASE-SENSITIVE.

  DEFINE VARIABLE i      AS INTEGER     NO-UNDO.
  DEFINE VARIABLE lFound AS LOGICAL     NO-UNDO INITIAL TRUE.

  cUText = CAPS(pcText).
  cLText = LC(pcText).
  DO i = 1 TO LENGTH(pcText):
    IF (SUBSTRING(cUText, i, 1)) <> (SUBSTRING(cLText, i, 1)) THEN
    DO:
      IF lFound THEN
      DO:
         SUBSTRING(cLText, i, 1) = (SUBSTRING(cUText, i, 1)).
         lFound = FALSE.
      END.
    END.
    ELSE lFound = TRUE.
  END.
  RETURN cLText.   

END FUNCTION.

Another issue is that title case is supposed to be language specific, i.e. verbs and nouns are treated differently to prepositions and conjunctions. These are some possible rules for title case:

1. First and last word always get capitalized
2. Capitalize all nouns, verbs (including "is" and other forms of "to be"), adverbs (including "than" and "when"), adjectives (including "this" and "that"), and pronouns (including "its").
3. Capitalize prepositions that are part of a verb phrase.
4. Lowercase articles (a, an, the).
5. Lowercase coordinate conjunctions (and, but, for, nor, or).
6. Lowercase prepositions of four or fewer letters.
7. Lowercase "to" in an infinitive phrase.
8. Capitalize the second word in compound words if it is a noun or proper adjective or the words have equal weight (Cross-Reference, Pre-Microsoft Software, Read/Write Access, Run-Time). Lowercase the second word if it is another part of speech or a participle modifying the first word (How-to, Take-off).

I could of course not code all this without teaching the computer English, so I created this version as a simple if crude compromise; it works in most cases, but there are exceptions.

FUNCTION TitleCaseE RETURNS CHARACTER
  ( pcText AS CHARACTER ) :
/*------------------------------------------------------------------------------
  Purpose: Converts an English string to Title Case.  
    Notes:          
------------------------------------------------------------------------------*/

  DEFINE VARIABLE i           AS INTEGER     NO-UNDO.
  DEFINE VARIABLE cWord       AS CHARACTER   NO-UNDO.
  DEFINE VARIABLE lFound      AS LOGICAL     NO-UNDO INITIAL TRUE.
  DEFINE VARIABLE iLast       AS INTEGER     NO-UNDO.

  DEFINE VARIABLE cSmallWords AS CHARACTER   NO-UNDO
     INITIAL "and,but,or,for,nor,the,a,an,to,amid,anti,as,at,but,by,down,from,in" + 
             ",into,like,near,of,off,on,onto,over,per,than,to,up,upon,via,with".

  pcText = REPLACE(REPLACE(LC(pcText),"-"," - "),"/"," / ").
  iLast = NUM-ENTRIES(pcText, " ").
  DO i = 1 TO iLast:
    cWord = ENTRY(i, pcText, " ").
    IF LENGTH(cWord) > 0 THEN
      IF i = 1 OR i = iLast OR LOOKUP(cWord, cSmallWords) = 0 THEN
        ENTRY(i, pcText, " ") = CAPS(SUBSTRING(cWord, 1, 1)) + LC(SUBSTRING(cWord, 2)).
  END.

  RETURN REPLACE(REPLACE(pcText," - ","-")," / ","/").   

END FUNCTION.

I have to mention that Tom's solution is very much faster than both of mine. Depending on what you need, you may find that the speed is not that important, since you're unlikely to use this in large data crunching processes or with long strings, but I wouldn't ignore it. Make sure that your needs justify the performance loss.