Upgrade from Mathematica 5 to Mathematica 7

I am trying to upgrade some equations that currently are written against Mathematica 5 to get them to work in Mathematica 7.

F = Graphics[
  ContourPlot[
   x^2 + (2)*y^2 + (-1)*((1)/(3))*x, {x, -1, 1}, {y, -1, 1}, 
   ContourShading -> False, ContourStyle -> {RGBColor[1, 0, 1]}, 
   Contours -> 20, PlotPoints -> 100]]; 
G = ParametricPlot[{Cos[u], Sin[u]}, {u, 0, 2*Pi}, 
  PlotStyle -> {RGBColor[0, 174/255, 239/255]}]; 
H = DeleteCases[F, {x_, y_} /; (x^2 + y^2 > 1), 5]; 
Show[{H, G}, AspectRatio -> Automatic, Frame -> False, Axes -> True, 
   AxesOrigin -> {0, 0}, AxesLabel -> {x, y}, Ticks -> None]

It should look like this:

and it gives the following error:

Thread::tdlen: Objects of unequal length in 
  {{},{},{},{},{},{},{},{},{},{},{},{},{},{},{},{},{},{},{},{},{}}+{{},<<21>>,{}} 
  cannot be combined. >>

and if you hover over the image you get the 开发者_如何学JAVAfollowing in a tooltip:

The specified setting for the option GraphicsBoxOptions, PlotRange cannot be used.
Coordinate index X is out of range for the enclosing GraphicsComplex

there are a lot of those Coordinate ones all with different coordinates.

And the second one I'm having difficulty with is:

P1 = {{(5)/10*Cos[u]*Cos[v], (5)/10*Sin[u]*Cos[v], (5)/10*Sin[v]}, {u,
    0, 2*Pi}, {v, -Pi/2, Pi/2}}; 
P2 = {{(5)/10*Cos[u], 0, (5)/10*Sin[u]}, {u, 0, 2*Pi}}; 
P3 = {{(5)/10*Cos[u], (5)/10*Sin[u], 0}, {u, 0, 2*Pi}}; 
P4 = {{0, (5)/10*Cos[u], (5)/10*Sin[u]}, {u, 0, 2*Pi}}; 
U = {P1, P2, P3, P4}; 
XL = {{-1, 1}, {-1, 1}, {-1, 1}}; 
XV = {{1, 0, 0}, {0, 1, 0}, {0, 0, 1}}; 
XS = {"x", "y", "z"}; 
f[a_, b_, c_] := {a, 1.1*b[[2]]*c}; 
g[a_, b_] := {(b*# &) /@ a}; 
T = Text @@@ MapThread[f, {XS, XL, XV}]; 
A = Line @@@ MapThread[g, {XL, XV}]; 
F = (ParametricPlot3D[Evaluate[Evaluate @@ #]][[1]] &) /@ U; 
OPT = {Boxed -> False, Axes -> False, BoxRatios -> {1, 1, 1}, PlotRange -> XL, 
  ViewPoint -> {2.4, 1.3, 2}, 
  DisplayFunction -> 
   Identity}; 
L = {LightSources -> {{{0.1, 0, 1}, RGBColor[0.68, 0.88, 0.96]}}}; 
gr1 = (Show[Graphics3D[#], OPT, L] &) /@ {{EdgeForm[], F}, {Dashing[{0.03, 0.03}], 
    GrayLevel[0.7], A}, {T}}; 
gr2 = DeleteCases[Graphics[Show[Graphics3D[{A, EdgeForm[], F}], OPT, 
        RenderAll -> False]], {__, _Polygon}, 3]; 
Show[{gr1, gr2}, AspectRatio -> Automatic]

This one should look like:

which and it gives these errors:

ParametricPlot3D::write: Tag Plus in x^2+y^2 is Protected. >>
Graphics3D::optx : Unknown option RenderAll
Graphics3D::optx : Unknown option LightSources

If I then remove the Unknown options, those errors disappear but it still looks wrong:

Also, if you hover over the last image in mathematica you get the following message repeated several times in a tooltip

Times is not a Graphics3D primitive or directive

Second one, great circles partly hidden, axes partly dashed:

r = 1.01/2; d = 1/(100 r);
v1 = Riffle[
   Table[r { Cos[\[Phi]], Sin[\[Phi]], -d}, {\[Phi], 0, 2 \[Pi], (
     2 \[Pi])/40.}], 
   Table[r {  Cos[\[Phi]], Sin[\[Phi]], d}, {\[Phi], 0, 2 \[Pi], (
     2 \[Pi])/40.}]];
v2 = Riffle[
   Table[-r {  Cos[\[Phi]], -d, Sin[\[Phi]]}, {\[Phi], 0, 2 \[Pi], (
     2 \[Pi])/40.}], 
   Table[-r { Cos[\[Phi]], d, Sin[\[Phi]]}, {\[Phi], 0, 2 \[Pi], (
     2 \[Pi])/40.}]];
v3 = Riffle[
   Table[r { -d, Cos[\[Phi]], Sin[\[Phi]]}, {\[Phi], 0, 2 \[Pi], (
     2 \[Pi])/40.}], 
   Table[r { d, Cos[\[Phi]], Sin[\[Phi]]}, {\[Phi], 0, 2 \[Pi], (
     2 \[Pi])/40.}]];
lx = {{{1, 0, 0}, {2, 0, 0}}}/2;
ly = {{{0, 1, 0}, {0, 2, 0}}}/2;
lz = {{{0, 0, 1}, {0, 0, 2}}}/2;
A2 = Line @@@ {lx, ly, lz, -lx, -ly, -lz};
Graphics3D[
 {
  FaceForm[None, Black], EdgeForm[],
  GraphicsComplex[#, 
     Table[Polygon[Mod[{i, i + 1, i + 3, i + 2}, Length[v], 1]], {i, 
       1, Length[v] - 1, 2}]] & /@ {v1, v2, v3}, {Opacity[0.75], 
   RGBColor[0.68`, 0.88`, 0.96`], Sphere[{0, 0, 0}, 1/2]},
  {Dashing[{0.02, 0.02}], Black, A}, T, A2
  },
 Boxed -> False, 
 Lighting -> {{"Directional", RGBColor[0.68`, 0.88`, 0.96`], 
    ImageScaled@{0.1, 0, 1}}}, BoxRatios -> {1, 1, 1}, 
 PlotRange -> {{-1, 1}, {-1, 1}, {-1, 1}}, 
 BaseStyle -> FontSize -> 14, ViewPoint -> {2.4`, 1.3`, 2}, 
 ViewVertical -> {0, 0, 1}
 ]

It is a little hard to tell from the picture what you want for the second graphic. Please try this and tell me what is right and what is lacking.

P1 = {{(5)/10*Cos[u]*Cos[v], (5)/10*Sin[u]*Cos[v], (5)/10*Sin[v]}, {u,
     0, 2*Pi}, {v, -Pi/2, Pi/2}};
P2 = {{(5)/10*Cos[u], 0, (5)/10*Sin[u]}, {u, 0, 2*Pi}};
P3 = {{(5)/10*Cos[u], (5)/10*Sin[u], 0}, {u, 0, 2*Pi}};
P4 = {{0, (5)/10*Cos[u], (5)/10*Sin[u]}, {u, 0, 2*Pi}};
U = {P1, P2, P3, P4};
XL = {{-1, 1}, {-1, 1}, {-1, 1}};
XV = {{1, 0, 0}, {0, 1, 0}, {0, 0, 1}};
XS = {"x", "y", "z"};
f[a_, b_, c_] := {a, 1.1*b[[2]]*c};
g[a_, b_] := {(b*# &) /@ a};
T = Text @@@ MapThread[f, {XS, XL, XV}];
A = Line @@@ MapThread[g, {XL, XV}];
F = ParametricPlot3D[##, Mesh -> False][[1]] & @@@ U;
OPT = {Boxed -> False, Axes -> False, BoxRatios -> {1, 1, 1}, 
   PlotRange -> XL, ViewPoint -> {2.4, 1.3, 2}};
L = Lighting -> {{"Directional", 
     RGBColor[0.68, 0.88, 0.96], {{5, 5, 4}, {5, 5, 0}}}};
gr1 = Graphics3D[#, OPT, L] & /@ {{Opacity[0.5], F},
                                  {Dashing[{0.03, 0.03}], GrayLevel[0.7], A},
                                  {T}};
Show[gr1]

Here is another take that may be closer to the original. You lose the v7 ability to rotate the graphic with this.

gr1 = Rasterize[Graphics3D[#, OPT, L], 
     Background -> None] & /@ {F, {Dashing[{0.03, 0.03}], 
     GrayLevel[0.7], A}, T};
Show[gr1]

First one:

ContourPlot[x^2 + (2)*y^2 + (-1)*((1)/(3))*x, {x, -1, 1}, {y, -1, 1}, 
 ContourShading -> False, ContourStyle -> {RGBColor[1, 0, 1]}, 
 Contours -> 20, RegionFunction -> (#1^2 + #2^2 <= 1 &), 
 BoundaryStyle -> Blue]

[Edit] Second one, using the given values for A and T:

Show[
 ParametricPlot3D[{(5)/10*Cos[u]*Cos[v], (5)/10*Sin[u]*Cos[v], (5)/10*
    Sin[v]}, {u, 0, 2*Pi}, {v, -Pi/2, Pi/2}, 
  MeshFunctions -> {#1 &, #2 &, #3 &}, PlotStyle -> Opacity[0.75], 
  Mesh -> {{0}, {0}, {0}}, MeshStyle -> Black, BoundaryStyle -> Black,
   Boxed -> False, Axes -> False, BoxRatios -> {1, 1, 1}, 
  PlotRange -> {{-1, 1}, {-1, 1}, {-1, 1}}, 
  ViewPoint -> {2.4`, 1.3`, 2}, 
  Lighting -> {{"Directional", RGBColor[0.68`, 0.88`, 0.96`], 
     ImageScaled@{0.1, 0, 1}}}],
 Graphics3D[{{Dashing[{0.03, 0.03}], Black, A}, {T}}]
 ]

• I think the axes will need to be done as separate interior/exterior segments.
• The great circles show through in this version; preventing that will require drawn partial curves instead of mesh lines, if that's required.